• 082226375801
  • alfianmaarif@ee.uad.ac.id
  • Yogyakarta
Materi
Tutorial ESP32: Cara Membuat Sistem Alarm Banjir Pintar (Flood Alarm IoT) dengan Notifikasi Peringatan Bahaya Real-Time ke Smartphone Menggunakan Sensor Ultrasonik HC-SR04, Buzzer Alarm, & Blynk IoT pada WOKWI

Tutorial ESP32: Cara Membuat Sistem Alarm Banjir Pintar (Flood Alarm IoT) dengan Notifikasi Peringatan Bahaya Real-Time ke Smartphone Menggunakan Sensor Ultrasonik HC-SR04, Buzzer Alarm, & Blynk IoT pada WOKWI

Pada bagian ini akan dibahas pembuatan sistem alarm peringatan dini banjir berbasis IoT (Flood Alarm IoT Notification System) menggunakan mikrokontroler ESP32, sensor jarak ultrasonik HC-SR04, buzzer alarm peringatan, serta platform Blynk IoT pada software simulasi WOKWI. Skematik rangkaian ditunjukkan pada Gambar 1, program Arduino pada Kode 1, dan video pembuatan pada tautan Video 1. Sistem mengukur jarak permukaan air secara berkala setiap 1 detik menggunakan fungsi pulseIn. Jika jarak air terdeteksi di bawah batas aman (< 15 cm), ESP32 mengaktifkan nada alarm pada buzzer, menyalakan widget Alarm and Sound di dashboard Blynk, serta mengirimkan notifikasi peringatan darurat (Blynk.logEvent) langsung ke smartphone pengguna, sekaligus mengirim nilai jarak aktual ke Datastream V1.

Gambar 1. Skematik rangkaian sistem

List Pin:

  • Sensor Ultrasonik HC-SR04 (Sensor Jarak / Ketinggian Air)
    Trig Pin => GPIO 5 (trigPin)
    Echo Pin => GPIO 18 (echoPin)
    VCC => 5V / 3.3V
    GND => GND
  • Aktuator Buzzer Alarm Peringatan
    Buzzer Positive (+) => GPIO 13 (buzzerPin)
    Buzzer Negative (-) => GND

List Virtual PIN:

  • V0 => Widget Alarm and Sound (Integer 0/1) – Mengaktifkan/Mematikan Widget Peringatan Suara & Visual Darurat Banjir di Dashboard Blynk saat Kondisi Kritis
  • V1 => Jarak Permukaan Air (Integer cm) – Datastream Widget Gauge / Label Real-Time Nilai Pembacaan Jarak dari Sensor Ultrasonik HC-SR04
// ============================= 
// ALFIAN CENTER 
// SUBSCRIBE 
// Tutorial ESP32 Bikin Alarm Banjir IoT dengan Fitur Notifikasi Cegah Banjir! Kirim Peringatan Bahaya Langsung ke Smartphone 
// PROGRAM BAKAL AKU KIRIM DENGAN SYARAT DIBAWAH 
// LIKE 50, KOMEN 20 DAN *WAJIB SUBSCRIBE*
// PROGRAM DIKIRIM VIA KOMENTAR 
// =============================

#define BLYNK_TEMPLATE_ID "MASUKKAN_ID_DISINI"
#define BLYNK_TEMPLATE_NAME "Alarm Banjir IoT"
#define BLYNK_AUTH_TOKEN "MASUKKAN_TOKEN_DISINI"

#include <WiFi.h>
#include <BlynkSimpleEsp32.h>

char auth[] = BLYNK_AUTH_TOKEN;
char ssid[] = "Wokwi-GUEST";
char pass[] = "";

const int trigPin = 5;
const int echoPin = 18;
const int buzzerPin = 13;

BlynkTimer timer;
bool sedangBanjir = false;

void cekBanjir() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  
  long durasi = pulseIn(echoPin, HIGH);
  int jarak = durasi * 0.034 / 2;

  // --- LOGIKA ALARM ---
  if (jarak < 15) { 
    // Jika air di bawah 15cm (BAHAYA)
    tone(buzzerPin, 1000); 
    
    if (sedangBanjir == false) {
      Blynk.virtualWrite(V0, 1); // Menyalakan widget "Alarm and Sound" di Web
      Blynk.logEvent("peringatan_banjir", "DARURAT! Air kritis!");
      sedangBanjir = true;
    }
  } 
  else {
    // Jika kondisi AMAN
    noTone(buzzerPin);
    
    if (sedangBanjir == true) {
      Blynk.virtualWrite(V0, 0); // Mematikan widget "Alarm and Sound" di Web
      sedangBanjir = false;
    }
  }

  // Kirim angka jarak ke Datastream V1 (Label atau Gauge)
  Blynk.virtualWrite(V1, jarak); 
  Serial.print("Jarak: "); Serial.println(jarak);
}

void setup() {
  Serial.begin(115200);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(buzzerPin, OUTPUT);

  Blynk.begin(auth, ssid, pass);
  timer.setInterval(1000L, cekBanjir);
}

void loop() {
  Blynk.run();
  timer.run();
}

Kode Arduino 1. Kode Program

Video 1. Video tutorial pembuatan

TAG:

alarm banjir iot esp32, notifikasi banjir smartphone blynk, sensor ultrasonik hc-sr04 esp32, blynk iot flood alarm, peringatan bahaya banjir wokwi, tutorial esp32 blynk, iot mitigasi bencana banjir, blynk logevent peringatan banjir, buzzer alarm banjir esp32, datastream blynk jarak air, virtual pin blynk alarm sound, kirim peringatan ke hp blynk, tutorial blynk iot esp32, gpio 5 18 ultrasonik pin, gpio 13 buzzer alarm, proyek iot esp32 smart water, tutorial wokwi indonesia, simulasi iot alarm banjir, pemantauan air jarak jauh blynk, blynk app flood notification, smart city iot esp32, proyek teknik elektro iot, mekatronika sistem peringatan banjir, tugas akhir iot flood alarm, skripsi iot notifikasi banjir, ide proyek esp32 iot, skematik alarm banjir esp32, diagram rangkaian ultrasonik buzzer esp32, source code alarm banjir esp32, program arduino blynk flood alarm, simulasi iot tanpa hardware, platform simulasi wokwi, wokwi esp32 flood alarm, blynk auth token esp32, alat peringatan banjir berbasis iot, telemetry data ultrasonik blynk, proyek sains iot elektro, portofolio iot esp32, praktikum mikrokontroler esp32, modul esp32 wroom 32, pinout esp32 ultrasonik buzzer, gpio esp32 sensor actuator, indikator status alarm blynk, grafik jarak permukaan air blynk, smart water management esp32, efisiensi mitigasi bencana banjir, panduan iot alarm banjir esp32, belajar mikrokontroler online, simulator komponen elektronik, wokwi custom chip esp32, blynk iot platform disaster warning, internet of things indonesia, iot smk teknik elektro, iot universitas teknik, prototipe alarm banjir esp32, alat deteksi air bah otomatis, iot smart environment, esp32 arduino ide blynk, tutorial iot pemula, proyek elektro water alarm, panduan lengkap wokwi blynk, sensor hc-sr04 jarak akurat, sistem informasi peringatan dini, logika batas jarak 15cm, notifikasi darurat blynk app, sistem pemantauan sungai tangki, otomatisasi sistem peringatan bahaya, proyek mekatronika elektro, simulasi hardware flood alarm, sistem alarm banjir esp32, proyek iot populer, kodingan alarm otomatis esp32, sensor ultrasonik digital esp32, rangkaian hc-sr04 dan buzzer, tutorial mikrokontroler iot, wawasan teknik elektro, aplikasi iot smart city, sistem deteksi banjir cerdas esp32, koding logika pulsein ultrasonik, pemantauan ketinggian air real time, iot flood alert management system

Leave a Reply

Your email address will not be published. Required fields are marked *